box_gs_vhelmh Subroutine

  subroutine box_gs_vhelmh(mg, id, nc, redblack_cntr)
    type(mg_t), intent(inout) :: mg
    integer, intent(in)       :: id
    integer, intent(in)       :: nc
    integer, intent(in)       :: redblack_cntr
    !< Iteration counter
    integer                   :: i, j, i0, di
    logical                   :: redblack
    real(dp)                  :: idr2(2*2), u(2*2)
    real(dp)                  :: a0, a(2*2), c(2*2)

    ! Duplicate 1/dr^2 array to multiply neighbor values
    idr2(1:2*2:2) = 1/mg%dr(:, mg%boxes(id)%lvl)**2
    idr2(2:2*2:2) = idr2(1:2*2:2)
    i0  = 1

    redblack = (mg%smoother_type == mg_smoother_gsrb)
    if (redblack) then
       di = 2
    else
       di = 1
    end if

    ! The parity of redblack_cntr determines which cells we use. If
    ! redblack_cntr is even, we use the even cells and vice versa.
    associate (cc => mg%boxes(id)%cc, n => mg_iphi, i_eps => mg_iveps)
      do j = 1, nc
         if (redblack) i0 = 2 - iand(ieor(redblack_cntr, j), 1)

         do i = i0, nc, di
            a0     = cc(i, j, i_eps)
            u(1:2) = cc(i-1:i+1:2, j, n)
            a(1:2) = cc(i-1:i+1:2, j, i_eps)
            u(3:4) = cc(i, j-1:j+1:2, n)
            a(3:4) = cc(i, j-1:j+1:2, i_eps)
            c(:)   = 2 * a0 * a(:) / (a0 + a(:)) * idr2

            cc(i, j, n) = (sum(c(:) * u(:)) - cc(i, j,&
                mg_irhs)) / (sum(c(:)) + vhelmholtz_lambda)
         end do
      end do
    end associate
  end subroutine box_gs_vhelmh