box_gs_lpl Subroutine

  subroutine box_gs_lpl(mg, id, nc, redblack_cntr)
    type(mg_t), intent(inout) :: mg
    integer, intent(in)       :: id
    integer, intent(in)       :: nc
    integer, intent(in)       :: redblack_cntr
    !< Iteration counter
    integer                   :: i, j, i0, di
    real(dp)                  :: idr2(2), fac
    logical                   :: redblack

    idr2 = 1/mg%dr(:, mg%boxes(id)%lvl)**2
    fac = 0.5_dp / sum(idr2)
    i0  = 1

    redblack = (mg%smoother_type == mg_smoother_gsrb)
    if (redblack) then
       di = 2
    else
       di = 1
    end if

    ! The parity of redblack_cntr determines which cells we use. If
    ! redblack_cntr is even, we use the even cells and vice versa.
    associate (cc => mg%boxes(id)%cc, n => mg_iphi)
      do j = 1, nc
         if (redblack) i0 = 2 - iand(ieor(redblack_cntr, j), 1)

         do i = i0, nc, di
            cc(i, j, n) = fac * ( idr2(1) * (cc(i+1, j, n) + cc(i-1, j,&
                n)) + idr2(2) * (cc(i, j+1, n) + cc(i, j-1, n)) - cc(i, j,&
                mg_irhs))
         end do
      end do
    end associate
  end subroutine box_gs_lpl